Conductor-backed coplanar waveguide

for HP 42S
Conductor-backed Coplanar Waveguide

Rev.0.8 (Jan. 26, 2022)
Takayuki HOSODA

Calculate the characteristic impedance and effective dielectric constant of a conductor-backed coplanar waveguide.

Usage

Operation

[XEQ] [cbcpw]

Input

MEM "er"   : Dielectric relative permittivity
MEM "h"    : Dielectric thickness
MEM "w"    : Conductor width
MEM "g"    : Conductor gap
MEM "t"    : Conductor thickness

Resources used

MEM  00    : K(k)
MEM  01    : K(k₃)
MEM  02    : K(k')
MEM  03    : K(k₃')

Output

REG t      : ε_eff - Effective relative permittivity
REG z      : ε_eff - Effective relative permittivity
REG y      : ε_eff - Effective relative permittivity
REG X      : Z₀  - Characteristic impedance [Ω]

Source code

Analyze Conductor-backed Coplanar Waveguide. Rev.0.8 (Jan. 26, 2022)
(c) 2022 Takayuki HOSODA

00 { 205-Byte Prgm }
01>LBL "K"          ; Complete elliptic integral of the first kind K(k)
02 X↑2
03 1
04 X<>Y
05 -
06 SQRT
07>LBL "K'"         ; K(k') | compensation modulus k' = √(1 - k²)
08 1
09>LBL 00
10 ENTER
11 ENTER
12 RCL× ST T
13 SQRT
14 R↓
15 R↓
16 +
17 0.5
18 ×
19 R↑
20 X=Y?
21 GTO 01
22 R↓
23 GTO 00
24>LBL 01
25 R↓
26 +
27 PI
28 X<>Y
29 ÷
30 RTN
31>LBL "cbcpw"
32 MVAR "er"
33 MVAR "h"
34 MVAR "w"
35 MVAR "g"
36 MVAR "t"
37 VARMENU "cbcpw"
38 STOP
39 EXITALL
40 RCL "t"
41 0
42 X≥Y?
43 GTO 02
44 X<>Y
45>LBL 02
46 ENTER            ; Conductor thickness compensation Δ              
47 RCL+ "w"         ; w + Δ
48 PI
49 4
50 RCL× "h"
51 ÷
52 RCL "g"
53 R↑
54 -                ; g - Δ
55 ENTER
56 +
57 R↑
58 +
59 R↑
60 RCL÷ ST Y
61 STO 00
62 R↑
63 RCL× ST T
64 TANH
65 R↑
66 RCL× ST T
67 TANH
68 ÷
69 STO 01
70 XEQ "K'"
71 STO 03
72 RCL 00
73 XEQ "K'"
74 STO 02
75 RCL 01
76 XEQ "K"
77 STO 01
78 RCL 00
79 XEQ "K"
80 STO 00
81 RCL 02
82 RCL× 01
83 RCL 00
84 RCL× 03
85 ÷
86 ENTER
87 RCL× "er"
88 1
89 +
90 X<>Y
91 1
92 +
93 ÷
94 ENTER            ; Effective permittivity ε_eff
95 SQRT
96 RCL 00
97 RCL÷ 02
98 RCL 01
99 RCL÷ 03
100 +
101 ×
102 188.365156834    ; Characteristic impedance of free space η₀ / 2
103 X<>Y
104 ÷
105 RTN              ; Characteristic impedance of the CBCPW Z₀
106 END

Download : cbcpw.raw (raw program file for Free42)

Example

Input

er = 4.6
h  = 200
w  = 220
g  = 100
t  = 18

Output

y: 3.03929179414
x: 53.8837578377

Formulas used ^{[1], [2]}

$Z_0 &=& \frac{\eta_0}{2 \sqrt{\varepsilon_\mathrm{eff}}} \frac{1}{\displaystyle \frac{K(k)}{K(k')} + \frac{K(k_3)}{K(k'_3)}}\\ \varepsilon_\mathrm{eff} &=& \frac{1 + \varepsilon_{r} \displaystyle\frac{K(k')}{K(k)}\frac{K(k_3)}{K(k'_3)}} {1 + \displaystyle\frac{K(k')}{K(k)}\frac{K(k_3)}{K(k'_3)}}$

where

$k &=& \frac{w}{w + 2g}\\ k_3 &=& \frac{\tanh\left(\displaystyle\frac{ \pi w}{4 h}\right)}{\tanh\left(\displaystyle\frac{\pi (w + 2g)}{4 h}\right)}\\ k' &=& \sqrt{1 - k^2} \\ k'_3 &=& \sqrt{1 - k_3^2}$
η₀ : Impedance of free space 376.730313668(57) Ω
and K(k) is the complete elliptic integral of the first kind.

The above analytical solution is for a negligibly thin conductor thickness, but the conductor thickness used in an actual circuit board has a non-negligible effect. The following formulas are used to compensate the effect of conductor thickness to center strip width w and slot widths g.

$\delta &=& t\\ w & \leftarrow & w + \delta \\ s & \leftarrow & s - \delta \\ d & \leftarrow & d - \delta$

REFERENCE

Rainee N. Simons, "Coplanar Waveguide Circuits, Components, and Systems", A JOHN WILEY & SONS, INC., PUBLICATIO N, 2001
Brian C. Wadell, "Transmission Line Design Handbook", Artech House, Inc., 1991, ISBN 0-89006-436-9

Usage

Source code

Example

Formulas used [1], [2]

REFERENCE

SEE ALSO

Formulas used ^{[1], [2]}