Synthesize/Analyze microstrip transmission line

for the HP 32sII
uZW - Synthesize/Analyze microstrip transmission line

Usage

Synthesize : XEQ W
Analyze    : XEQ Z

Input

MEM E : relative permittivity
MEM H : dielectric height           [mm]
MEM T : conductor thickness         [mm]
REG x : line impedance              [Ω]  (Synthesize)
      | microstrip line width       [mm] (Analyze)

Resources used

MEM E : relative permittivity
MEM H : dielectric height           [mm]
MEM R : velocity of propagation
MEM T : conductor thickness         [mm]
MEM W : Microstrip line width       [Ω]
MEM Z : characteristic impedance    [Ω]

Output

MEM R : velocity of propagation
MEM W : Microstrip line width       [Ω]  (Synthesized)
MEM Z : characteristic impedance    [Ω]  (Analyzed)

REG t : rightangle bend compensation
REG z : open end compensation       [mm]
REG y : velocity of propagation
REG χ : microstrip line width       [mm] (Synthesized)
    | : characteristic impedance    [Ω]  (Analyzed)

Program list

μZW ‐ Rev. 1.76 : Jan. 24, 2012


LBL W     
STO Z 
8
RCL× H 
1
RCL+ E
SQRT
RCL× Z
72
÷
e^χ
÷
STO W 
FN= X
SOLVE W
STO W
XEQ Y
RCL W
RTN


LBL X     
4
RCL× H
RCL H
11
10
÷
RCL× T
RCL+ W
π
×
÷
χ²
1
+
SQRT
RCL× T
÷
LN
1
+
RCL× T
π
÷
RCL E
1/χ
1
+
2
÷
×
LASTχ
π
χ²
4
R↑
RCL+ W



÷
RCL× H
ENTER
R↓
R↓
×
8
RCL÷ E
14
+
11
÷
R↑
×
ENTER
R↓
χ²
+
SQRT
R↑
+
×
1
+
LN
42.397056
1
RCL+ E
SQRT
÷
×
RCL- Z
RTN


LBL Y     
1
χ<> E
STO R
XEQ X
RCL+ Z
RCL÷ Z
1/χ
χ<> R
STO E


         
103
250
÷
RCL× H
3
10
÷
RCL+ E
×
0.262
RCL W
RCL÷ H
+
LASTχ
0.813
+
-0.258
RCL+ E
×
1/χ
×
×


         
-27
RCL× W
20
RCL× H
÷
e^χ
65
×
52
+
100
÷
χ≤0?
CLχ
RCL R
RTN


LBL Z     
STO W
CLχ
STO Z
XEQ X
STO Z
XEQ Y
RCL Z
RTN

W (CK=2624 028.5) : Synthesize
X (CK=5C87 113.0) : Effective width
Y (CK=96BA 104.0) : Velocity of propagation, Open-end compensation, and
Rightangle bend compensation (valid for 0.25 ≤ W/H ≤ 2.75, 2.5 ≤ ε_r ≤ 25, VSWR ≤ 1.1 [2](i.e. S₁₁ ≤ -26dB))
Z (CK=1EFC 013.5) : Analyze (Characteristic impedance error ≤ 2% [1])

Formulas used

Micro strip line impedance

where,
$w_\mathrm{eff} & \simeq & w + t \frac{1 + \displaystyle\frac{1}{\varepsilon_\mathrm{r}}}{2 \pi}\left(1 + \ln \left( \frac{4}{ \sqrt{\left(\displaystyle\frac{t}{h}\right)^2 +\left(\displaystyle\frac{1}{\pi}\frac{1}{\displaystyle\frac{w}{t} + 1.1}\right)^2} } \right)\right)$

Right bend compensation

$R_\mathrm{miter} & = & 0.52 + 0.65 \ e^{\displaystyle\left(\frac{-1.35\ w}{h} \right)}$

Example (Synthesize)

Input

3.5    STO E
0.400  STO H     
0.018  STO T    
50     XEQ W

Output

MEM R : 608.477373E-3
MEM W : 877.596205E-3 
MEM Z : 50.00000000E0

REG t : 157.769272E-3
REG z : 553.618791E-3
REG y : 608.477373E-3
REG χ : 877.596205E-3

REFERENCES

H. A. Wheeler, "Transmission-line properties of a strip on a dielectric sheet on a plane",
IEEE Trans. Microwave Theory Tech., vol. MTT-25, pp.631-647, Aug. 1977.
R. J. Douville and D. S. James, "Experimental study of symmetric microstrip bends and their compensation",
IEEE Trans. Microwave Theory Tech., vol. MTT-26, pp. 175-182, Mar. 1978

Usage

Input

Resources used

Output

Program list

Formulas used

Example (Synthesize)

REFERENCES

SEE ALSO