LPFMF - Multiple feedback Band-Pass-Filter / HP-42S

for the HP 42S
LPFMF - Calculate voltage gain, center frequency and Q of a multiple-feedback low-pass-filter.

Multiple feedback low-pass-filter

Input

Var R1: Resistance [Ω]
Var R2: Resistance [Ω]
Var R3: Resistance [Ω]
Var C1: Capacitance [F]
Var C2: Capacitance [F]

Resources to be used

REG 00: ω ‐ natural angular frequency


Output


Var h : h ‐ Gain coefficient
Var Q : Q ‐ Quality factor
Var Fc: f_c ‐ Center frequency [Hz]
REG z : h ‐ Gain coefficient
REG y : Q ‐ Quality factor
REG x : f_c ‐ Center frequency [Hz]



Program list


LPFMF - Rev.1.00 : Aug. 1 2011



00 { 164-Byte Prgm }
01 LBL "LPFMF"
02 MVAR "R1"
03 MVAR "R2"
04 MVAR "R3"
05 MVAR "C1"
06 MVAR "C2"
07 VARMENU "LPFMF"
08 STOP
09 EXITALL
10 RCL "R1"
11 1/X
12 RCL "R2"
13 1/X
14 RCL "R3"
15 1/X
16 +
17 +
18 1/X
19 RCL "C1"
20 RCL "C2"
21 RCL× "R2"
22 RCL× "R3"
23 ÷
24 SQRT
25 ×
26 STO "Q"
27 RCL "C1"
28 RCL× "C2"
29 RCL× "R2"
30 RCL× "R3"
31 SQRT
32 ENTER
33 +
34 PI
35 ×
36 1/X
37 STO "Fc"
38 RCL "R2"
39 RCL÷ "R1"
40 +/-
41 CLA
42 ENG 03
43 "Q="
44 ARCL "Q"
45 ", h="
46 ARCL ST X
47 "^L_FFc="
48 ARCL "Fc"
49 " [Hz] LPFMF"
50 AVIEW
51 RCL "Q"
52 RCL "Fc"
53 ENG 11
54 RTN
55 .END.








Example


Input
R1 = 30e3
R2 = 30e3
R3 = 15e3
C1 = 3e-9
C2 = 750e-12

Output
z: -1.0000000000E0
y: 707.106781187E-3
x: 5.00175731198E3








Download 'LPFMF-1.0'
(lpfmf.raw, 167 byte, raw program file for the
 Free42)







© 2000 Takayuki HOSODA.


Powered by