Conductor-backed coplanar waveguide

for HP Prime
Conductor-backed Coplanar Waveguide

Calculate the characteristic impedance and effective dielectric constant of a conductor-backed coplanar waveguide.

Usage

SYNOPSIS

cbcpw(ϵ_r, h, w, g, t)

ARGUMENTS

ϵ_r   : Dielectric relative permittivity
h    : Dielectric thickness
w    : Conductor width
g    : Conductor gap (slot width)
t    : Conductor thickness

RETURN VALUES

Z₀, ϵ_eff  : Characteristic impedance, Effective relative permittivity

Source code

Analyze Conductor-backed Coplanar Waveguide. Rev.0.50 (Jan. 7, 2023)
(c) 2022 Takayuki HOSODA

#CAS
/* cbcpw - Analyze Conductor-Backed Coplanar Waveguide. 
 * Rev. 0.80 (Jan. 26, 2023) (c) 2022 Takayuki HOSODA
 */
CAS_EPSILON := 7.1054273576E-15;
/* complete elliptic integral of the first kind.
 * The argument k is modulus.
 */
EllipticK(k):=
BEGIN
  LOCAL a, b, m, c;
  c := 2 * CAS_EPSILON * max(abs(a := 1), abs(b := sqrt(1 - (m := k * k))));
  REPEAT
    m := 0.5 * (a + b);
    b := sqrt(a * b);
    a := m;
  UNTIL abs(a - b) < c;
  return PI / (a + b);
END;
EllipticRatio(k):=
BEGIN
  return EllipticK(k) / EllipticK(sqrt(1 - k * k)); 
END;
/* Conductor-backed coplanar waveguide */
cbcpw(er, h, w, g, t):=
BEGIN
  LOCAL we, ge, k1, k2, r1, r2, ere, z;
  LOCAL d := 0;
  IF t > 0 THEN
    d := t;
  END;
  we := w + d;
  ge := g - d;
  r1 := EllipticRatio(we / (we + 2 * ge));
  r2 := EllipticRatio(tanh(PI * we / (4 * h)) / tanh(PI * (we + 2 * ge) / (4 * h)));
  ere := (r1 + er * r2) / (r1 + r2); 
  z := 188.365156834 / (sqrt(ere) * (r1 + r2));
  /* 
  PRINT("cbcpw - Conductor backed coplanar waveguide:");
  PRINT("ϵ = " + er + ", h = " + h + ", w = " + w + ", g = " + g + " ,t = " + t);
  PRINT("ϵ_e = " + ere);
  PRINT("Z₀ = " + z);
  */
  return z, ere;
END;
#END

Download : cbcpw.hpprgm (raw program file for the HP Prime)

Example

Input

cbcpw(4.6, 200, 220, 100, 18)

Output

[53.8837578377 3.03929179414]

Formulas used ^{[1], [2]}

$Z_0 &=& \frac{\eta_0}{2 \sqrt{\varepsilon_\mathrm{eff}}} \frac{1}{\displaystyle \frac{K(k)}{K(k')} + \frac{K(k_3)}{K(k'_3)}}\\ \varepsilon_\mathrm{eff} &=& \frac{1 + \varepsilon_{r} \displaystyle\frac{K(k')}{K(k)}\frac{K(k_3)}{K(k'_3)}} {1 + \displaystyle\frac{K(k')}{K(k)}\frac{K(k_3)}{K(k'_3)}}$

where

$k &=& \frac{w}{w + 2g}\\ k_3 &=& \frac{\tanh\left(\displaystyle\frac{ \pi w}{4 h}\right)}{\tanh\left(\displaystyle\frac{\pi (w + 2g)}{4 h}\right)}\\ k' &=& \sqrt{1 - k^2} \\ k'_3 &=& \sqrt{1 - k_3^2}$
η₀ : Impedance of free space 376.730313668(57) Ω
and K(k) is the complete elliptic integral of the first kind.

Effective center strip width w_e and slot widths g_e are obtained by applying the following correction Δ for the effect of conductor thickness t.

$\Delta &=& \frac{5 t}{4 \pi} \left( 1 + \ln\left(\displaystyle\frac{4 \pi w}{t}\right)\right)\\ w_e &=& w + \Delta\\ g_e &=& g - \Delta$

REFERENCE

Rainee N. Simons, "Coplanar Waveguide Circuits, Components, and Systems", A JOHN WILEY & SONS, INC., PUBLICATIO N, 2001
Brian C. Wadell, "Transmission Line Design Handbook", Artech House, Inc., 1991, ISBN 0-89006-436-9

Usage

Source code

Example

Formulas used [1], [2]

REFERENCE

SEE ALSO

Formulas used ^{[1], [2]}